Excel VBA 窗体之特殊形状窗体 几何形状组合窗体 实现代码
发布时间:2022-04-30 05:56:20
在VBA中我们有时需要一些特殊形状的窗体来美化我们的程序,比如说几个几何形状的组合样式的窗体。那我们就来作一个同心圆形状的窗体: 本示例主要运用 API 函数来定制化Excel中的用户窗体,使其显示特殊形状
附件下载:
操作如下:
◾在Excel的VBE窗口中插入一个用户窗体,将其命名为EspecialForm。然后再添加一个模块。然后在窗体和模块中添加后面所列代码。
◾在工作薄中的任意工作表中添加一窗体按钮控件,将指定其设置宏为ShowForm。其供示范之用
具体代码:
"mdEspecial"模块代码
Sub btnShowEspecial_Click()
frmEspecial.Show
End Sub
"frmEspecial" 窗体代码
Option Explicit
'**********************************
'---此模块主要是创建了一个圆环窗体---
'**********************************
'以下声明API函数
#If Win64 Then '64位
'视情况向和窗体发送消息
Private Declare PtrSafe Function SendMessage _
Lib "user32" _
Alias "SendMessageA" ( _
ByVal Hwnd As LongPtr, _
ByVal wMsg As Long, _
ByVal wParam As LongPtr, _
lParam As Any) _
As LongPtr
'创建一个内切于矩形的椭圆
Private Declare PtrSafe Function CreateEllipticRgn _
Lib "gdi32" ( _
ByVal X1 As Long, _
ByVal Y1 As Long, _
ByVal X2 As Long, _
ByVal Y2 As Long) _
As LongPtr
'以特定的方式合并区域
Private Declare PtrSafe Function CombineRgn _
Lib "gdi32" ( _
ByVal hDestRgn As LongPtr, _
ByVal hSrcRgn1 As LongPtr, _
ByVal hSrcRgn2 As LongPtr, _
ByVal nCombineMode As Long) _
As Long
'给窗体设置区域,而舍弃此区域外的其他区域
Private Declare PtrSafe Function SetWindowRgn _
Lib "user32" ( _
ByVal Hwnd As LongPtr, _
ByVal hRgn As LongPtr, _
ByVal bRedraw As Long) _
As Long
'查找窗口
Private Declare PtrSafe Function FindWindow _
Lib "user32" _
Alias "FindWindowA" ( _
ByVal lpClassName As String, _
ByVal lpWindowName As String) _
As LongPtr
'释放鼠标
Private Declare PtrSafe Function ReleaseCapture _
Lib "user32" () _
As Long
#Else
'视情况向和窗体发送消息
Private Declare Function SendMessage _
Lib "user32" _
Alias "SendMessageA" ( _
ByVal Hwnd As Long, _
ByVal wMsg As Long, _
ByVal wParam As Long, _
ByVal lParam As Long) _
As Long
'创建一个内切于矩形的椭圆
Private Declare Function CreateEllipticRgn _
Lib "gdi32" ( _
ByVal X1 As Long, _
ByVal Y1 As Long, _
ByVal X2 As Long, _
ByVal Y2 As Long) _
As Long
'以特定的方式合并区域
Private Declare Function CombineRgn _
Lib "gdi32" ( _
ByVal hDestRgn As Long, _
ByVal hSrcRgn1 As Long, _
ByVal hSrcRgn2 As Long, _
ByVal nCombineMode As Long) _
As Long
'给窗体设置区域,而舍弃此区域外的其他区域
Private Declare Function SetWindowRgn _
Lib "user32" ( _
ByVal Hwnd As Long, _
ByVal hRgn As Long, _
ByVal bRedraw As Long) _
As Long
'查找窗口
Private Declare Function FindWindow _
Lib "user32" _
Alias "FindWindowA" ( _
ByVal lpClassName As String, _
ByVal lpWindowName As String) _
As Long
'释放鼠标
Private Declare Function ReleaseCapture _
Lib "user32" () _
As Long
#End If
'声明常数及变量
Private Const WM_SYSCOMMAND = &H112
Private Const SC_MOVE_MOUSE = &HF012&
Private Const RGN_XOR = 3 '两个源区域并集之外的部分
#If Win64 Then '64位
Dim FHwnd As LongPtr
Dim FRgn1 As LongPtr
Dim FRgn2 As LongPtr
#Else
Dim FHwnd As Long
Dim FRgn1 As Long
Dim FRgn2 As Long
#End If
'窗体双击
Private Sub UserForm_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Unload Me
End Sub
'窗体初始化
Private Sub UserForm_Initialize()
FRgn1 = CreateEllipticRgn(10, 40, 200, 230) '创建一个圆
FRgn2 = CreateEllipticRgn(30, 60, 180, 210) '创建一个圆
CombineRgn FRgn1, FRgn1, FRgn2, RGN_XOR '合并两个圆,取其不相交的部分
FHwnd = FindWindow(vbNullString, Me.Caption) '查找窗体句柄
SetWindowRgn FHwnd, FRgn1, 1 '设置窗体区域,一个圆环
End Sub
'窗体鼠标按下
Private Sub UserForm_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
ReleaseCapture '释放鼠标
SendMessage FHwnd, WM_SYSCOMMAND, SC_MOVE_MOUSE, 0
End Sub
Excel VBA 窗体之特殊形状窗体 几何形状组合窗体 实现代码的下载地址:
猜你喜欢
- Excel是一个很棒的程序,具有数百个有用的功能。不幸的是,缺少一个功能是一种合并两个或更多列同时保留其所有数据的简单方法。如果尝试在两列上
- 基于表格的用户接口的最大问题是:由于采用Excel黙认方式来处理数据的剪切、复制、粘贴以及拖放,而数据输入表中大多数用于编辑的单元格都被指定
- 页面设置命令组页边距使用页边距命令,设置整个文档或当前部分的边距大小。边距大小可从几种常用边距格式中选择,或者自定义新的边距格式。纸张方向使
- 1、执行“工具→自动更正”命令,打开“自动更正”对话框。2、在“替换”下面的方框中输入“pcw”(也可以是其他字符,“pcw”用小写),在“
- 1、打开Excel2010,点击“数据”选项卡,然后在最左边的“获取外部数据”菜单中选择“自文本”选项。 2、在“
- 1.4 Excel工作表的基本操作工作表包含在工作簿中,因此工作表的操作都是在工作簿中进行的。工作表的操作主要包括选取工作表、重
- word2010怎样绘制一个简单的圆形电子印章?下面和小编一起来看看具体步骤吧word2010怎样绘制一个简单的圆形电子印章?下面和小编一起
- 在日常操作word表格的过程中,我们可能会遇到这种现象:标题跑到表格下方去了,怎么恢复也恢复不了。如图:标题跑到word表格下方去了 图1
- 每到期末,老师都需要给每个学生家长发放一份通知书,其中包括学生成绩、评语等内容,以前大家往往是采用手工填写或者打印,必须要繁琐地对学生成绩进
- 小编最近在编写技术文章的时候想到要在一个Word文档里插入另外一篇Word文档,然后当我需要阅读另外一篇文档的时候,直接点击就能够打开,在
- 在Word文档的工作中,word绘制的表格中想要输入相同的内容,或者有特定规律的内容,需要了解的过程是什么。以下是小编为您带来的关于word
- 在这之前已经给大家介绍过了很多关于日期的函数,今天我们来给大家介绍DAYS360 函数,这个函数的特点是按照一年 360 天的算法(每个月以
- 关于excel身份证提取出生年月,本文分享两种函数公式提取和使用分列技巧来提取出生年月.excel身份证提取出生年月,是我们在学习MID函数
- 经常被人问到怎么对两份Excel数据进行比对,提问的往往都很笼统;在工作中,有时候会需要对两份内容相近的数据记录清单进行比对,需求不同,比对
- 双面打印设置:方法一:1、打开打印机按“属性”2、在打印机属性中安双面打印选项下拉菜单3、纸张纵向,选择“双面打印,长边装订”;纸张横向,选
- word文字右上角设①方法如下:1、鼠标点击要插入脚注的地方,然后点击引用选项卡。2、点击脚注功能组右下角箭头,弹出脚注对话框,在位置那里选
- 在Excel中录入好数据以后经常需要统计数据,而图表则是统计数据最好的辅助功能,下面让小编为你带来excel2010制作饼图的方法。exce
- 1.打开需要使用朗读功能的WPS文档 2.点击工具栏的“特色功能”,然后我们就可以看到“朗读”功能,除了“全文朗读
- 如下图,excel虚线怎么去掉,这个虚线是打印线,一般在打印浏览的时候容易出现。那么怎么才能将这烦人的虚线删除呢?今天,小编就教大家在Exc
- 有些小伙伴会在使用电脑的时候不小心删除掉原本有管理员权限的账号,导致自己只剩下了只剩下了普通权限的账号,那么遇到这种情况要怎么办呢?下面就和